Htykuut

My Access database is split into back and front-end.
I have created an Access form in the front-end that contains a textBox, a Browser button and a Relink button.

When I click Browse, file manager pops up to choose my .mdb file. After the file is choosen, the path to the file is displayed into the textBox.

What I want is when I press Relink button, it should take the path from textBox and link my back-end file to my front end.

Here is my code so far:

'browse button

 Private Sub browseBtn_Click()

   Dim objDialog As Object

   set objDialog = Application.FileDialog(3)

   With objDialog

        .show

        .AllowMultiSelect = False

        If .SelectedItems.Count = 1 Then

            'textFiled displays the path

             Me.textField = .SelectedItems(1) 

        End If

    End With

 End Sub



'relink button

Private Sub linkBtn_Click()

    Dim newConnection As String

    Dim currentPath As String

    currentPath = Me.textField

    Dim tblDef As TableDef

        tblDef.Connect = newConnection

        tblDef.RefreshLink

End Sub

What is wrong with this?

I've figure it out in the end, here is the full code:

Private Sub browseBtn_Click()

Dim objDialog As Object



 Set objDialog = Application.FileDialog(3)



 With objDialog

   .title = "Please select the backend file"

   .AllowMultiSelect = False

   .Show

   If .SelectedItems.Count = 1 Then

    Me.textField = .SelectedItems(1)

   End If

 End With

End Sub



Private Sub linkBtn_Click()

  RefreshLinks (Me.textField)

End Sub





Public Function RefreshLinks(strFilename As String)

   Dim dbs As dao.Database

   Dim tdf As TableDef



   Set dbs = CurrentDb



    For Each tdf In dbs.TableDefs

         If Len(tdf.Connect) > 0 Then

             tdf.Connect = ";DATABASE=" & strFilename

             Err = 0

            On Error Resume Next

            tdf.refreshlink

             If Err <> 0 Then

                RefreshLinks = False

                 Exit Function

             End If

         End If

    Next tdf

    RefreshLinks = True



End Function